Setup/Setup.nsi

@@ -0,0 +1,124 @@
+!include "MUI2.nsh"
+
+!searchparse /file ..\version.h `#define MAJOR ` MAJOR
+!searchparse /file ..\version.h `#define MINOR ` MINOR
+
+!define REGPATH "Software\EqualizerAPO"
+
+;--------------------------------
+;General
+
+  ;Name and file
+  Name "Equalizer APO ${MAJOR}.${MINOR}"
+
+  ;Default installation folder
+  InstallDir "$PROGRAMFILES64\EqualizerAPO"
+
+  ;Request application privileges for Windows Vista
+  RequestExecutionLevel admin
+
+;--------------------------------
+;Interface Settings
+
+  !define MUI_ABORTWARNING
+  !define MUI_COMPONENTSPAGE_NODESC
+
+;--------------------------------
+;Pages
+
+  !insertmacro MUI_PAGE_WELCOME
+  !insertmacro MUI_PAGE_LICENSE ..\License.txt
+  !insertmacro MUI_PAGE_DIRECTORY
+  !insertmacro MUI_PAGE_INSTFILES
+  !insertmacro MUI_PAGE_FINISH
+
+  !insertmacro MUI_UNPAGE_WELCOME
+  !insertmacro MUI_UNPAGE_CONFIRM
+  !insertmacro MUI_UNPAGE_COMPONENTS
+  !insertmacro MUI_UNPAGE_INSTFILES
+  !insertmacro MUI_UNPAGE_FINISH
+
+;--------------------------------
+;Languages
+
+  !insertmacro MUI_LANGUAGE "English"
+  !insertmacro MUI_LANGUAGE "German"
+
+;--------------------------------
+;Installer Sections
+
+Section "Install" SecInstall
+  SetRegView 64
+
+  SetOutPath "$INSTDIR"
+  SetRebootFlag true
+
+  File "${BINPATH}\EqualizerAPO.dll"
+  File "${BINPATH}\Configurator.exe"
+  File "${BINPATH}\Benchmark.exe"
+  
+  File "${LIBPATH}\libsndfile-1.dll"
+  File "${LIBPATH}\msvcp100.dll"
+  File "${LIBPATH}\msvcr100.dll"
+  
+  CreateDirectory "$INSTDIR\config"
+  
+  SetOverwrite off
+  File /oname=config\config.txt "config\config.txt"
+  File /oname=config\example.txt "config\example.txt"
+  SetOverwrite on
+
+  ;Grant write access to the config directory for all users
+  AccessControl::GrantOnFile "$INSTDIR\config" "(S-1-5-32-545)" "FullAccess"
+
+  WriteRegStr HKLM ${REGPATH} "InstallPath" "$INSTDIR"
+  WriteRegStr HKLM ${REGPATH} "ConfigPath" "$INSTDIR\config"
+  WriteRegStr HKLM ${REGPATH} "EnableTrace" "false"
+
+  WriteUninstaller "$INSTDIR\Uninstall.exe"
+  
+  WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Audio" "DisableProtectedAudioDG" 1
+  ;RegDLL doesn't work for 64 bit dlls
+  ExecWait '"$SYSDIR\regsvr32.exe" /s "$INSTDIR\EqualizerAPO.dll"'
+
+  ExecWait '"$INSTDIR\Configurator.exe" /i'
+  
+SectionEnd
+
+;--------------------------------
+;Uninstaller Sections
+
+LangString SecRemoveName ${LANG_ENGLISH} "Remove configurations and registry backups"
+LangString SecRemoveName ${LANG_GERMAN} "Konfigurationen und Registrierungsbackups entfernen"
+
+Section /o un.$(SecRemoveName)
+  
+  Delete "$INSTDIR\*.reg"
+  RMDir /REBOOTOK /r "$INSTDIR\config"
+  
+SectionEnd
+
+Section "-un.Uninstall"
+  SetRegView 64
+
+  ExecWait '"$INSTDIR\Configurator.exe" /u'
+  
+  ExecWait '"$SYSDIR\regsvr32.exe" /u /s "$INSTDIR\EqualizerAPO.dll"'
+  DeleteRegValue HKLM "Software\Microsoft\Windows\CurrentVersion\Audio" "DisableProtectedAudioDG"
+
+  Delete /REBOOTOK "$INSTDIR\msvcr100.dll"
+  Delete /REBOOTOK "$INSTDIR\msvcp100.dll"
+  Delete "$INSTDIR\libsndfile-1.dll"
+  
+  Delete "$INSTDIR\Benchmark.exe"
+  Delete "$INSTDIR\Configurator.exe"
+  Delete /REBOOTOK "$INSTDIR\EqualizerAPO.dll"
+
+  Delete "$INSTDIR\Uninstall.exe"
+
+  ;Only remove if empty
+  RMDir /REBOOTOK "$INSTDIR"
+
+  DeleteRegKey /ifempty HKLM ${REGPATH}
+
+SectionEnd

Setup/Setup32.nsi

@@ -0,0 +1,16 @@
+
+!define BINPATH "..\Release"
+!define LIBPATH "lib32"
+
+!include "Setup.nsi"
+
+LangString VersionError ${LANG_ENGLISH} "This installer is only supposed to be run on 32-Bit Windows. Please use the 64-Bit installer."
+LangString VersionError ${LANG_GERMAN} "Dieses Installationsprogramm kann nur auf einem 32-Bit-Windows verwendet werden. Bitte nutzen Sie die 64-Bit-Version."
+
+Function .onInit
+	StrCmp $PROGRAMFILES32 $PROGRAMFILES64 +3
+	MessageBox MB_OK|MB_ICONSTOP $(VersionError)
+	Abort
+FunctionEnd
+
+OutFile "EqualizerAPO32-${MAJOR}.${MINOR}.exe"

Setup/Setup64.nsi

@@ -0,0 +1,16 @@
+
+!define BINPATH "..\x64\Release"
+!define LIBPATH "lib64"
+
+!include "Setup.nsi"
+
+LangString VersionError ${LANG_ENGLISH} "This installer is only supposed to be run on 64-Bit Windows. Please use the 32-Bit installer."
+LangString VersionError ${LANG_GERMAN} "Dieses Installationsprogramm kann nur auf einem 64-Bit-Windows verwendet werden. Bitte nutzen Sie die 32-Bit-Version."
+
+Function .onInit
+	StrCmp $PROGRAMFILES32 $PROGRAMFILES64 0 +3
+	MessageBox MB_OK|MB_ICONSTOP $(VersionError)
+	Abort
+FunctionEnd
+
+OutFile "EqualizerAPO64-${MAJOR}.${MINOR}.exe"

Setup/config/config.txt

@@ -0,0 +1,2 @@
+Preamp: -6 db
+Include: example.txt

Setup/config/example.txt

@@ -0,0 +1,30 @@
+Filter Settings file
+
+Room EQ V5,01
+Dated: 29.02.2012 20:04:50
+
+Notes:Simple bass boost
+
+Equaliser: Generic
+No measurement
+Filter  1: ON  PK       Fc    20,0 Hz  Gain   4,0 dB  Q  1,00
+Filter  2: ON  PK       Fc    45,0 Hz  Gain   2,0 dB  Q  1,00
+Filter  3: OFF None   
+Filter  4: OFF None   
+Filter  5: OFF None   
+Filter  6: OFF None   
+Filter  7: OFF None   
+Filter  8: OFF None   
+Filter  9: OFF None   
+Filter 10: OFF None   
+Filter 11: OFF None   
+Filter 12: OFF None   
+Filter 13: OFF None   
+Filter 14: OFF None   
+Filter 15: OFF None   
+Filter 16: OFF None   
+Filter 17: OFF None   
+Filter 18: OFF None   
+Filter 19: OFF None   
+Filter 20: OFF None   
+